Indicatore batteria Atmega328p e Attiny85

Indicatore_batteria_attiny85_atmega328pA volte capita di voler misurare la tensione della batteria di un Atmega328p o un Attiny85, per sapere in anticipo quando cambiarla o ricaricarla, bene in questa pagina vedremo come fare un semplice indicatore di livello batteria usando tre led.
Se alimentassimo il nostro microcontrollore a meno di 5V e in modo non stabilizzato, per esempio da una batteria LiPo e provassimo a misurare la tensione della batteria direttamente dal pin analogico A0 avremo una lettura falsata in quanto non avremmo il riferimento di 5V.
Usando questo codice è possibile misurare la tensione di alimentazione direttamente e senza usare pin analogici, usando il riferimento interno di 1,1V.

int ledv=0;
int ledg=1;
int ledr=2;
long result;
long vbatt=0;

void setup(void)
{
pinMode(ledr,OUTPUT);
pinMode(ledg,OUTPUT);
pinMode(ledv,OUTPUT);
}

void loop()
{
 vbatt=readVcc();
 if(vbatt>=3800)
 {
 digitalWrite(ledv,HIGH);
 digitalWrite(ledg,LOW);
 digitalWrite(ledr,LOW);
 }
 else if(vbatt<3800&&vbatt>=3700)
 {
 digitalWrite(ledv,LOW);
 digitalWrite(ledg,HIGH);
 digitalWrite(ledr,LOW);
 }
else if(vbatt<3700)
 {
 digitalWrite(ledv,LOW);
 digitalWrite(ledg,LOW);
 digitalWrite(ledr,HIGH);
 }
}

long readVcc()
{
// Read 1.1V reference against AVcc
// set the reference to Vcc and the measurement to the internal 1.1V reference
#if defined(__AVR_ATmega32U4__) || defined(__AVR_ATmega1280__) || defined(__AVR_ATmega2560__)
ADMUX = _BV(REFS0) | _BV(MUX4) | _BV(MUX3) | _BV(MUX2) | _BV(MUX1);
#elif defined (__AVR_ATtiny24__) || defined(__AVR_ATtiny44__) || defined(__AVR_ATtiny84__)
ADMUX = _BV(MUX5) | _BV(MUX0);
#elif defined (__AVR_ATtiny25__) || defined(__AVR_ATtiny45__) || defined(__AVR_ATtiny85__)
ADMUX = _BV(MUX3) | _BV(MUX2);
#else
ADMUX = _BV(REFS0) | _BV(MUX3) | _BV(MUX2) | _BV(MUX1);
#endif

delay(2); // Wait for Vref to settle
ADCSRA |= _BV(ADSC); // Start conversion
while (bit_is_set(ADCSRA,ADSC)); // measuring
uint8_t low = ADCL; // must read ADCL first - it then locks ADCH
uint8_t high = ADCH; // unlocks both
long result = (high<<8) | low;
result = 1125300L / result; // Calculate Vcc (in mV); 1125300 = 1.1*1023*1000
return result; // Vcc in millivolts
}

Nel codice troviamo ledv, ledg, ledr, che corrispondo ai led verde, giallo e rosso, leggiamo i millivolt restituiti dalla funzione readVcc(), per approfondire sulla funzione readVcc potete visitare questo sito, e la mettiamo nella variabile vbatt, poi semplicemente confrontiamo i millivolt restituiti dalla funzione con delle soglie di tensione impostabili a piacere.
In questo caso oltre 3800mV si accenderà il led verde, tra 3800 e 3700mV il led giallo, sotto i 3700mV il led rosso.
In foto ho usato una batteria LiPo carica e per misurare le varie soglie ho usato un diodo 1n4819, con una caduta di circa 0,3V, un diodo 1n4007 con una caduta di 0,7V e un ponticello da circa 0V.

Indicatore_batteria_attiny85_atmega328p1 Indicatore_batteria_attiny85_atmega328p2

 

Indicatore_batteria_attiny85_atmega328p3

Funziona anche con l’Atmega328p.

Indicatore_batteria_attiny85_atmega328p4 Indicatore_batteria_attiny85_atmega328p5

Indicatore_batteria_attiny85_atmega328p6

Il valore del riferimento interno di 1,1V varia da chip a chip e la tolleranza è di circa 10%, per migliorare l’accuratezza, bisogna fare delle prove e misurare la tensione con un voltmetro e cambiare la costante 1125300 con un valore adeguato.
Per l’atmega328p è invece possibile misurare direttamente la tensione del riferimento interno tra Vref e massa usando questo codice:

void setup ()
{
analogReference(INTERNAL);
analogRead(A0);
}
void loop()
{}

Una volta letta con un voltmetro sarà possibile poi sostituirla nella formula, per avere un’accuratezza migliore.

Indicatore_batteria_attiny85_atmega328p7
Ora potete dotare i vostri progetti di un indicatore di livello batteria, un saluto e alla prossima.

I commenti sono chiusi.